加载中...

LiveScript

其中 Y=LiveScript

源代码下载： learnLivescript.ls

LiveScript 是一种具有函数式特性且编译成 JavaScript 的语言，能对应 JavaScript 的基本语法。 还有些额外的特性如：柯里化，组合函数，模式匹配，还有借镜于 Haskell，F# 和 Scala 的许多特点。

LiveScript 诞生于 Coco，而 Coco 诞生于 CoffeeScript。 LiveScript 目前已释出稳定版本，开发中的新版本将会加入更多特性。

非常期待您的反馈，你可以通过 @kurisuwhyte 与我连系 :)

  1. # 与 CoffeeScript 一样，LiveScript 使用 # 单行注解。
  3. /*
  4.  多行注解与 C 相同。使用注解可以避免被当成 JavaScript 输出。
  5. */
  1. # 语法的部份，LiveScript 使用缩进取代 {} 来定义区块，
  2. # 使用空白取代 () 来执行函数。
  4. ########################################################################
  5. ## 1\. 值类型
  6. ########################################################################
  8. # `void` 取代 `undefined` 表示未定义的值
  9. void            # 与 `undefined` 等价但更安全（不会被覆写）
  11. # 空值则表示成 Null。
  12. null
  14. # 最基本的值类型数据是罗辑类型：
  15. true
  16. false
  18. # 罗辑类型的一些别名，等价于前者：
  19. on; off
  20. yes; no
  22. # 数字与 JS 一样，使用倍精度浮点数表示。
  23. 10
  24. 0.4     # 开头的 0 是必要的
  26. # 可以使用底线及单位后缀提高可读性，编译器会自动略过底线及单位后缀。
  27. 12_344km
  29. # 字串与 JS 一样，是一种不可变的字元序列：
  30. "Christina"             # 单引号也可以！
  31. """Multi-line
  32.    strings
  33.    are
  34.    okay
  35.    too."""
  37. # 在前面加上 \ 符号也可以表示字串：
  38. \keyword                # => 'keyword'
  40. # 数组是值的有序集合。
  41. fruits =
  42.   * \apple
  43.   * \orange
  44.   * \pear
  46. # 可以用 [] 简洁地表示数组：
  47. fruits = [ \apple, \orange, \pear ]
  49. # 你可以更方便地建立字串数组，并使用空白区隔元素。
  50. fruits = <[ apple orange pear ]>
  52. # 以 0 为起始值的数组下标获取元素：
  53. fruits[0]       # => "apple"
  55. # 对象是无序键值对集合（更多给节将在下面章节讨论）。
  56. person =
  57.   name: "Christina"
  58.   likes:
  59.     * "kittens"
  60.     * "and other cute stuff"
  62. # 你也可以用更简洁的方式表示对象：
  63. person = {name: "Christina", likes: ["kittens", "and other cute stuff"]}
  65. # 可以通过键值获取值：
  66. person.name     # => "Christina"
  67. person["name"]  # => "Christina"
  69. # 正则表达式的使用跟 JavaScript 一样：
  70. trailing-space = /\s$/          # dashed-words 变成 dashedWords
  72. # 你也可以用多行描述表达式!（注解和空白会被忽略）
  73. funRE = //
  74.         function\s+(.+)         # name
  75.         \s* \((.*)\) \s*        # arguments
  76.         { (.*) }                # body
  77.         //
  79. ########################################################################
  80. ## 2\. 基本运算
  81. ########################################################################
  83. # 数值操作符与 JavaScript 一样：
  84. 1 + 2   # => 3
  85. 2 - 1   # => 1
  86. 2 * 3   # => 6
  87. 4 / 2   # => 2
  88. 3 % 2   # => 1
  90. # 比较操作符大部份也一样，除了 `==` 等价于 JS 中的 `===`，
  91. # JS 中的 `==` 在 LiveScript 里等价于 `~=`，
  92. # `===` 能进行对象、数组和严格比较。
  93. 2 == 2          # => true
  94. 2 == "2"        # => false
  95. 2 ~= "2"        # => true
  96. 2 === "2"       # => false
  98. [1,2,3] == [1,2,3]        # => false
  99. [1,2,3] === [1,2,3]       # => true
  101. +0 == -0     # => true
  102. +0 === -0    # => false
  104. # 其它关系操作符包括 <、<=、> 和 >=
  106. # 罗辑值可以通过 `or`、`and` 和 `not` 结合：
  107. true and false  # => false
  108. false or true   # => true
  109. not false       # => true
  111. # 集合也有一些便利的操作符
  112. [1, 2] ++ [3, 4]                # => [1, 2, 3, 4]
  113. 'a' in <[ a b c ]>              # => true
  114. 'name' of { name: 'Chris' }     # => true
  116. ########################################################################
  117. ## 3\. 函数
  118. ########################################################################        
  120. # 因为 LiveScript 是函数式特性的语言，你可以期待函数在语言里被高规格的对待。
  121. add = (left, right) -> left + right
  122. add 1, 2        # => 3
  124. # 加上 ! 防止函数执行后的返回值
  125. two = -> 2
  126. two!
  128. # LiveScript 与 JavaScript 一样使用函式作用域，且一样拥有闭包的特性。
  129. # 与 JavaScript 不同的地方在于，`=` 变量赋值时，左边的对象永远不用变量宣告。
  131. # `:=` 操作符允许*重新賦值*父作用域里的变量。
  133. # 你可以解构函数的参数，从不定长度的参数结构里获取感兴趣的值。
  134. tail = ([head, ...rest]) -> rest
  135. tail [1, 2, 3]  # => [2, 3]
  137. # 你也可以使用一元或二元操作符转换参数。当然也可以预设传入的参数值。
  138. foo = (a = 1, b = 2) -> a + b
  139. foo!    # => 3
  141. # 你可以以拷贝的方式传入参数来避免副作用，例如：
  142. copy = (^^target, source) ->
  143.   for k,v of source => target[k] = v
  144.   target
  145. a = { a: 1 }
  146. copy a, { b: 2 }        # => { a: 1, b: 2 }
  147. a                       # => { a: 1 }
  149. # 使用长箭号取代短箭号来柯里化一个函数：
  150. add = (left, right) --> left + right
  151. add1 = add 1
  152. add1 2          # => 3
  154. # 函式里有一个隐式的 `it` 变量，意谓着你不用宣告它。
  155. identity = -> it
  156. identity 1      # => 1
  158. # 操作符在 LiveScript 里不是一個函数，但你可以简单地将它们转换成函数！
  159. # Enter the operator sectioning：
  160. divide-by-2 = (/ 2)
  161. [2, 4, 8, 16].map(divide-by-2) .reduce (+)
  163. # LiveScript 里不只有应用函数，如同其它良好的函数式语言，你可以合并函数获得更多发挥：
  164. double-minus-one = (- 1) . (* 2)
  166. # 除了普通的数学公式合并 `f . g` 之外，还有 `>>` 和 `<<` 操作符定义函数的合并顺序。
  167. double-minus-one = (* 2) >> (- 1)
  168. double-minus-one = (- 1) << (* 2)
  170. # 说到合并函数的参数, LiveScript 使用 `|>` 和 `<|` 操作符将参数传入：
  171. map = (f, xs) --> xs.map f
  172. [1 2 3] |> map (* 2)            # => [2 4 6]
  174. # 你也可以选择填入值的位置，只需要使用底线 _ 标记：
  175. reduce = (f, xs, initial) --> xs.reduce f, initial
  176. [1 2 3] |> reduce (+), _, 0     # => 6
  178. # 你也能使 _ 让任何函数变成偏函数应用：
  179. div = (left, right) -> left / right
  180. div-by-2 = div _, 2
  181. div-by-2 4      # => 2
  183. # 最后，也很重要的，LiveScript 拥有後呼叫特性， 可以是基於回调的代码
  184. # （你可以试试其它函数式特性的解法，比如 Promises）：
  185. readFile = (name, f) -> f name
  186. a <- readFile 'foo'
  187. b <- readFile 'bar'
  188. console.log a + b
  190. # 等同於：
  191. readFile 'foo', (a) -> readFile 'bar', (b) -> console.log a + b
  193. ########################################################################
  194. ## 4\. 模式、判断和流程控制
  195. ########################################################################
  197. # 流程控制可以使用 `if...else` 表达式：
  198. x = if n > 0 then \positive else \negative
  200. # 除了 `then` 你也可以使用 `=>`
  201. x = if n > 0 => \positive
  202.     else        \negative
  204. # 过於复杂的流程可以用 `switch` 表达式代替：
  205. y = {}
  206. x = switch
  207.   | (typeof y) is \number => \number
  208.   | (typeof y) is \string => \string
  209.   | 'length' of y         => \array
  210.   | otherwise             => \object      # `otherwise` 和 `_` 是等价的。
  212. # 函数主体、宣告式和赋值式可以表式成 `switch`，这可以省去一些代码：
  213. take = (n, [x, ...xs]) -->
  214.                         | n == 0 => []
  215.                         | _      => [x] ++ take (n - 1), xs
  217. ########################################################################
  218. ## 5\. 推导式
  219. ########################################################################
  221. # 在 JavaScript 的标准函式库里有一些辅助函数能帮助处理列表及对象
  222. #（LiveScript 则带有一个 prelude.ls ，作为标准函式库的补充 ）， 
  223. # 推导式能让你使用优雅的语法且快速地处理这些事：
  224. oneToTwenty = [1 to 20]
  225. evens       = [x for x in oneToTwenty when x % 2 == 0]
  227. # 在推导式里 `when` 和 `unless` 可以当成过滤器使用。
  229. # 对象推导式在使用上也是同样的方式，差别在于你使用的是对象而不是数组：
  230. copy = { [k, v] for k, v of source }
  232. ########################################################################
  233. ## 6\. OOP
  234. ########################################################################
  236. # 虽然 LiveScript 是一门函数式语言，但具有一些命令式及面向对象的特性。
  237. # 像是 class 语法和一些借镜於 CoffeeScript 的类别继承语法糖：
  238. class Animal
  239.   (@name, kind) ->
  240.     @kind = kind
  241.   action: (what) -> "*#{@name} (a #{@kind}) #{what}*"
  243. class Cat extends Animal
  244.   (@name) -> super @name, 'cat'
  245.   purr: -> @action 'purrs'
  247. kitten = new Cat 'Mei'
  248. kitten.purr!      # => "*Mei (a cat) purrs*"
  250. # 除了类别的单一继承模式之外，还提供了像混入 (Mixins) 这种特性。
  251. # Mixins 在语言里被当成普通对象：
  252. Huggable =
  253.   hug: -> @action 'is hugged'
  255. class SnugglyCat extends Cat implements Huggable
  257. kitten = new SnugglyCat 'Purr'
  258. kitten.hug!     # => "*Mei (a cat) is hugged*"

延伸阅读

LiveScript 还有许多强大之处，但这些应该足够启发你写些小型函数式程式了。 LiveScript有更多关于 LiveScript 的资讯 和线上编译器等着你来试！

你也可以参考 prelude.ls，和一些 #livescript 的网络聊天室频道。

还没有评论.