加载中...

clojure macros

其中 Y=clojure macros

源代码下载： learnclojuremacros-zh.clj

和所有Lisp一样，Clojure内在的同构性使得你可以穷尽语言的特性，编写生成代码的子过程——“宏”。宏是一种按需调制语言的强大方式。

小心！可以用函数完成的事用宏去实现可不是什么好事。你应该仅在需要控制参数是否或者何时eval的时候使用宏。

你应该熟悉Clojure.确保你了解Y分钟学Clojure中的所有内容。

  1. ;; 使用defmacro定义宏。宏应该输出一个可以作为clojure代码演算的列表。
  2. ;;
  3. ;; 以下宏的效果和直接写(reverse "Hello World")一致。
  5. (defmacro my-first-macro []
  6.   (list reverse "Hello World"))
  8. ;; 使用macroexpand或macroexpand-1查看宏的结果。
  9. ;;
  10. ;; 注意，调用需要引用。
  11. (macroexpand '(my-first-macro))
  12. ;; -> (#<core$reverse clojure.core$reverse@xxxxxxxx> "Hello World")
  14. ;; 你可以直接eval macroexpand的结果
  15. (eval (macroexpand '(my-first-macro)))
  16. ; -> (\d \l \o \r \W \space \o \l \l \e \H)
  18. ;; 不过一般使用以下形式，更简短，更像函数：
  19. (my-first-macro)  ; -> (\d \l \o \r \W \space \o \l \l \e \H)
  21. ;; 创建宏的时候可以使用更简短的引用形式来创建列表
  22. (defmacro my-first-quoted-macro []
  23.   '(reverse "Hello World"))
  25. (macroexpand '(my-first-quoted-macro))
  26. ;; -> (reverse "Hello World")
  27. ;; 注意reverse不再是一个函数对象，而是一个符号。
  29. ;; 宏可以传入参数。
  30. (defmacro inc2 [arg]
  31.   (list + 2 arg))
  33. (inc2 2) ; -> 4
  35. ;; 不过，如果你尝试配合使用引用列表，会导致错误，
  36. ;; 因为参数也会被引用。
  37. ;; 为了避免这个问题，clojure提供了引用宏的另一种方式：`
  38. ;; 在`之内，你可以使用~获得外圈作用域的变量。
  39. (defmacro inc2-quoted [arg]
  40.   `(+ 2 ~arg))
  42. (inc2-quoted 2)
  44. ;; 你可以使用通常的析构参数。用~@展开列表中的变量。
  45. (defmacro unless [arg & body]
  46.   `(if (not ~arg)
  47.      (do ~@body))) ; 别忘了 do!
  49. (macroexpand '(unless true (reverse "Hello World")))
  51. ;; ->
  52. ;; (if (clojure.core/not true) (do (reverse "Hello World")))
  54. ;; 当第一个参数为假时，(unless)会演算、返回主体。 
  55. ;; 否则返回nil。
  57. (unless true "Hello") ; -> nil
  58. (unless false "Hello") ; -> "Hello"
  60. ;; 需要小心，宏会搞乱你的变量
  61. (defmacro define-x []
  62.   '(do
  63.      (def x 2)
  64.      (list x)))
  66. (def x 4)
  67. (define-x) ; -> (2)
  68. (list x) ; -> (2)
  70. ;; 使用gensym来获得独有的标识符
  71. (gensym 'x) ; -> x1281 (or some such thing)
  73. (defmacro define-x-safely []
  74.   (let [sym (gensym 'x)]
  75.     `(do
  76.        (def ~sym 2)
  77.        (list ~sym))))
  79. (def x 4)
  80. (define-x-safely) ; -> (2)
  81. (list x) ; -> (4)
  83. ;; 你可以在 ` 中使用 # 为每个符号自动生成gensym
  84. (defmacro define-x-hygenically []
  85.   `(do
  86.      (def x# 2)
  87.      (list x#)))
  89. (def x 4)
  90. (define-x-hygenically) ; -> (2)
  91. (list x) ; -> (4)
  93. ;; 通常会配合宏使用帮助函数。
  94. ;; 让我们创建一些帮助函数来支持（无聊的）算术语法：
  96. (declare inline-2-helper)
  97. (defn clean-arg [arg]
  98.   (if (seq? arg)
  99.     (inline-2-helper arg)
  100.     arg))
  102. (defn apply-arg
  103.   "Given args [x (+ y)], return (+ x y)"
  104.   [val [op arg]]
  105.   (list op val (clean-arg arg)))
  107. (defn inline-2-helper
  108.   [[arg1 & ops-and-args]]
  109.   (let [ops (partition 2 ops-and-args)]
  110.     (reduce apply-arg (clean-arg arg1) ops)))
  112. ;; 在创建宏前，我们可以先测试
  113. (inline-2-helper '(a + (b - 2) - (c * 5))) ; -> (- (+ a (- b 2)) (* c 5))
  115. ; 然而，如果我们希望它在编译期执行，就需要创建宏
  116. (defmacro inline-2 [form]
  117.   (inline-2-helper form)))
  119. (macroexpand '(inline-2 (1 + (3 / 2) - (1 / 2) + 1)))
  120. ; -> (+ (- (+ 1 (/ 3 2)) (/ 1 2)) 1)
  122. (inline-2 (1 + (3 / 2) - (1 / 2) + 1))
  123. ; -> 3 (事实上，结果是3N, 因为数字被转化为带/的有理分数）

扩展阅读

Clojure for the Brave and True系列的编写宏 http://www.braveclojure.com/writing-macros/

官方文档 http://clojure.org/macros

何时使用宏？ http://dunsmor.com/lisp/onlisp/onlisp_12.html

还没有评论.